.TITLE RESET TERMINAL AFTER VAXLINK

;

; Installed as PRIV so users don't need PHY_IO

; Terminal reset to ECHO,TYPEAHEAD,INTERACTIVE,EVEN PARITY,NOEIGHTBIT

; The speed is specified as TT$C_BAUD_xxx in the SET_CHAR control block

; at label SETM below.

; UEA terminals are currently : TTA6 on PMS 11/750 1200 baud. MICOM P40

; TTA7 on VILLAGE 11/780 300 baud. MICOM P35

; If other characteristics change then the TT$M_ masks at label T4

; will need to be corrected.

;****** CPC 11780 mods 14/04/83

;****** reset to ECHO,TYPEAHEAD,INTERACTIVE,NOPARITY,NOEIGHTBIT

;****** TTA2 on CPC 11/780 300 baud. MICOM P129

;

.PSECT DATA

$IODEF

.MACRO TESTREP ARG1,ARG2

BLBS R0,ARG1

MOVL ARG2,REPLY

BRW ERROR

.ENDM TESTREP

XR0: .LONG 0

REPLY: .LONG 0

TDESC: .LONG 64 ;MAX LENGTH EVER ..

.LONG TBUF

TBUF: .LONG 0

CBUF: .LONG 0

TC: .LONG 0 ;TERMINAL CHARACTERISTICS

.BLKB 52 ;REST OF BUFFER .. NOT ACCESSED

SETM: $QIO EFN=1,FUNC=IO$_SETCHAR,IOSB=IOSBS,P1=CBUF,-

P3=TT$C_BAUD_300,P5=TT$M_ALTRPAR

CHANO: .WORD 0

IOSBS: .BLKW 1

IOSBL: .BLKW 1

IOSBD: .BLKL 1

TOUT: .ASCID/TERMOUT/

DEVOL:

DEVO: .LONG 63

DOA: .LONG DOB

DOB: .BLKB 63 ;DEVICE DESCRIPTOR

;

;

;

.PSECT CODE

START:: .WORD 0

$TRNLOG_S TOUT,DEVOL,DEVO

TESTREP T1,#1

T1:

$ALLOC_S DEVNAM=DEVO

TESTREP T2,#2

T2:

$ASSIGN_S DEVNAM=DEVO,CHAN=CHANO

TESTREP T3,#3

T3:

MOVZWL CHANO,QIO$_CHAN+SETM

$GETCHN_S CHAN=CHANO,PRIBUF=TDESC

TESTREP T4,#4

T4:

BICL2 #TT$M_NOECHO,TC

BICL2 #TT$M_PASSALL,TC

BICL2 #TT$M_NOTYPEAHD,TC

BICL2 #TT$M_EIGHTBIT,TC

$QIOW_G SETM

TESTREP T5,#5

T5:

$EXIT_S

ERROR:

MOVL R0,XR0

$DASSGN_S CHAN=CHANO

PUSHAL REPLY

PUSHAL XR0

CALLS #2,MONITOR

$EXIT_S

.END START